Tally TDL How to Add Custom field (UDF) on any screen of Tally.ERP9 Software

How to Add Custom field (UDF) on any screen of Tally.ERP9 Software

In this post we will learn how to add Custom Field on any Screen of Tally.ERP9 Software. I will be taking example of Sales Screen as this is the one of which we get most enquiry of or we our-self require most of the time to capture more information which is ether required during sales entry or want to print some additional information on our Invoice.

In this post we will be taking example of scenario where we want to view contact person of Customer.

So before we start you will need to have any text editor software installed on your system (e.g Notepad, WordPad etc…) but if you have Tally Developer 9 Application it will help us a lot. I am going to use Tally Developer 9 Application here

If you don’t have Tally Developer 9 application you can download it from http://tallysolutions.com/downloads. To know how to install it please read through my other blog how to install Tally Developer 9Application.

Start your Tally Developer 9 Application. Create a New Project (To know how to use Tally Developer 9 Application click here)

After creating a New Project now we need to decide where we want to have our field placed. In this example I have decided to place my field on the Top Right hand side of the screen in line of Ledger name. You can choose yours.

In the below code we have given a call to the line by using ‘#’ were we want to place are custom field.

[#Line: EI Consignee]

    Field       : Simple Prompt, EI Consignee, EI CurrConsignee, EI FirstLedger, INVMailName, Name field

    RightFields : Short Prompt, EI PriceLevel, EI PrevPriceLevel

The line may contain lot of default field.  We have do decide after or before which field we want our custom field. I have decided to place is just before Price level prompt which we see on screen use below code.

   Add: Right Field: After:Short Prompt: CustomerNamePrompt, CustomerName

After placing the field we need to provide contain to the field.

[Field:CustomerNamePrompt]

   Use: Medium Prompt                        ;; here I am saying that this is a prompt .

   Set as: "Contact Person"                    ;; The data in the prompt is Contact Person.                               

               

[Field:CustomerName]

    Use: Name Field              ;; This is going to be a normal text field which is called name field in tally       

    Set as:$LedgerContact:Ledger:$LedgerName    ;; At this place I am giving a call to contact person from Ledger Master which is selected.

    Set Always: Yes

    Skip: Yes

Which mean my code is

[#Line: EI Consignee]

    Field       : Simple Prompt, EI Consignee, EI CurrConsignee, EI FirstLedger, INVMailName, Name field

    RightFields : Short Prompt, EI PriceLevel, EI PrevPriceLevel

   Add: Right Field: After:Short Prompt: CustomerNamePrompt, CustomerName

[Field:CustomerNamePrompt]

   Use: Medium Prompt                       

   Set as: "Contact Person"                           

               

[Field:CustomerName]

    Use: Name Field                          

    Set as:$LedgerContact:Ledger:$LedgerName   

    Set Always: Yes

    Skip: Yes

And After attaching this code to you Tally.ERP9 Software you should be able to see the new fields Contact person and its name on sales screen.

Note:- make sure that you have turned on contact details in your ledger from F12 Settings and filled in contact person field.

Half page GST invoice Customization (Free TDL Code)

What is an Invoice?

An invoice is a commercial document that itemizes a transaction between a buyer and a seller. If goods or services were purchased on credit, the invoice usually specifies the terms of the deal, and provides information on the available methods of payment. An invoice is also known as a bill or sales invoice.

BREAKING DOWN 'Invoice'

 Companies may opt to simply send a month-end statement as the invoice for all outstanding transactions. If this is the case, the statement must indicate that no subsequent invoices will be sent.

An invoice must state it is an invoice on the face of the bill. It typically has a unique identifier called the invoice number that is useful for internal and external reference. An invoice typically contains contact information for the seller or service provider in case there is an error relating to the billing. Payment terms may be outlined on the invoice, as well as the information relating to any discounts, early payment details or finance charges assessed for late payments. It also presents the unit cost of an item, total units purchased, freight, handling, shipping and associated tax charges, and it outlines the total amount owed.

Importance of Invoice Date

The invoice date represents the official date in which the goods have been billed. Therefore, the invoice date has essential information regarding payment, as it dictates the credit duration and due date of the bill.

Invoice and Accounts  payable

Invoices track the sale of a product for inventory control, accounting and tax purposes. Many companies ship the product and expect payments on a later date, so the total amount due becomes an account payable for the buyer and an account receivable for the seller. Modern-day invoices are transmitted electronically, rather than being paper-based. If an invoice is lost, the buyer may request a copy from the seller. The use of an invoice represents the presence of credit, as the seller has sent a product or provided a service without receiving cash up front.

Invoices and Internal Controls

Invoices are a critical element of accounting internal controls. Charges on an invoice must be approved by the responsible management personal. Alternatively, an invoice is matched to a purchase order and upon reconciling the information payment is made for approved transactions. An auditing firm ensures invoices are entered into the appropriate accounting period when testing for expense cut-off.

GST A5 Invoice customization

After receiving lot of email’s and request for GST Invoice customization on half page i.e. A5 Landscape. I have tried to make a simple design which fits on A5 paper size in Landscape mode. But to achieve it I had to remove few things which were provided to you in A4 Customization which was posted earlier.

Note: - There is no GST Analysis in this code and no bank details and This is only for local sales so no IGST part.

To attach this code in your Tally.ERP 9 Application please visit http://tallyexperttips.blogspot.in/2017/09/how-to-attach-any-tallyerp9.html

Please find the below code for A5 GST invoice customization

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;GST Invoice Print;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

[Style:P9]

          Font:Calibri (Body)

          Height:9

         

[Style:P9B]

          Use:P9

          Bold: Yes

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

[#Part: VTYP BehaviourMain]

          Option                  : VTYP BehaveMain KA VchTypeConfirm : @@IsKAVchType

         

[!Part : VTYP BehaveMain KAVchTypeConfirm]

                   Add             : Line          : After : VTYP PrintSave :VTYP KA VchTypeConfirm

            

[Line           : VTYP KA VchTypeConfirm]

          Field : Long Prompt, Logical Field

          Local : Field : Long Prompt      : Set as        : "Print GST Format ?"

          Local : Field : Long Prompt      : Width                 : @@LongWidth

          Local : Field : Logical Field : Storage : KAVchTypeConfirm1  

[System : Formula]

          IsKAVchType                           : $$IsSales:$Parent

          IsKANewAllow                        : $KAVchTypeConfirm1:VoucherType:$VoucherTypeName 

         

[System : UDF]

          KAVchTypeConfirm1 : Logical          : 1782

         

[#Form : Sales Color]

          Option: KASalesKA Color: @@IsKANewAllow

         

[!Form:KASalesKA Color]

          Delete                   : Print

          Add             : Print : STC GST INVOICE KA

         

[Report :STC GST INVOICE KA]

          Use                       : Printed Invoice

          Delete: Form        : Printed Invoice

          Form                              : STC GST INVOICE KA

         

[Form:STC GST INVOICE KA]

          Width                   : 8 Inch

          Height                   : 6 Inch

    Space Top   : 0.10 Inch

    Space Right : 0.10 inch

    Space Left  : 0.50 inch

    Space Bottom: 0.10 inch

         

          Part: KA Opening Page Break, KA Invoice Body

          Bottom Part: KA Invoice Total, KA Goods Sold

         

          Page Break   : ClKA Page Break, KA Opening Page Break

         

[Part:ClKA Page Break]

          Lines           : GIKA ClPgBrk

          [Line: GIKA ClPgBrk]

                   Fields          : Simple Field

                   Local: Field: Simple Field          : Set As       : "Continued..."

                   Local: Field: Simple Field          : FullWidth  : Yes

                   Local: Field: Simple Field          : Align                  : Right

                   Border                   : Full Thin Top

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

[Part: KA Opening Page Break]

          Part: KA Invoice Title, KA CMP Details, KA Leading Details, KA Coloumn Titles

          Vertical: Yes

         

[Part:KA Invoice Title]

          Line:KA Invoice Title

         

[Line:KA Invoice Title]

          Field: Simple Field

          Right Field:Name Field

          Local: Field: Simple Field: Set as: "TAX INVOICE"

          Local: Field: Simple Field: Style: Large Bold

          Local: Field: Simple Field: Space Left: 45

          Local: Field: Simple Field: Full Width: Yes

          Local: Field: Name Field: Set as:If @@GetCopyNum = 1 Then "ORIGINAL FOR RECIPIENT" Else +

                                                                               If @@GetCopyNum = 2 Then $$LocaleString:"DUPLICATE FOR SUPPLIER" Else +

                                                                         If @@GetCopyNum = 3 Then $$LocaleString:"TRIPLICATE FOR TRANSPOTER" Else +

                                                                         If @@GetCopyNum = 4 Then $$LocaleString:"EXTRA COPY" Else $$LocaleString:"EXTRA COPY"

                                                                              

[Part:KA CMP Details]

          Part: DMICash CMP Name Details

         

         

[Part:DMICash CMP Name Details]

          Line: KA CMP Name, KA CMP Address

         

[Line: KA CMP Name]

          Field: Name Field

          Local: Field: Name Field: Set as: @@CmpMailName

          Local: Field: Name Field: Style:Parth CMP Name Cash

          Local: Field: Name Field: Full Width: Yes

         

[Style: Parth CMP Name Cash]

          Font: Adobe Garamond Pro Bold

          Height:15

          Bold: Yes

         

[Line:KA CMP Address]

          Field: Name Field

          Local: Field: Name Field: Set as: $$FullList:CompanyAddress:$Address

          Local: Field: Name Field: Width:50% Page

          Local: Field: Name Field: Line:0

          Local: Field: Name Field: Style:P9

         

[Part:KA Leading Details]

          Left Part: KA Customer Details

          Right Part: KA Invoice Details

          Border: Thick Cover

         

[Part:KA Customer Details]

          Line:KA Customer Details Title, KA Customer Name, KA Customer Address, KA Customer State Name, KA Customer GST No, KA Customer Contact

          Width: 70% Page

         

[Line:KA Customer Details Title]

          Field: Simple Field

          Local: Field: Simple Field : Set as: "Details for Buyer (Billed & Shipped To )"

          Local: Field: Simple Field: Style:P9B

          Local: Field: Simple Field: Full Width: Yes

         

[Line:KA Customer Name]

          Field: Simple Field

          Local: Field: Simple Field: Set as: @@SimpleOtherPartyName

          Local: Field: Simple Field: Style: P9B

          Local: Field: Simple Field: Full Width: Yes

          Space Top:0.5

         

[Line:KA Customer Address]

          Field: Simple Field

          Local: Field: Simple Field: Set as: $$FullList:BasicBuyerAddress:$BasicBuyerAddress

          Local: Field: Simple Field: Style: P9

          Local: Field: Simple Field: Full Width: Yes

          Local: Field: Simple Field: Line:0

         

[Line:KA Customer State Name]

          Field: Simple Field

          Local: Field: Simple Field: Set as: "State Name"+"  :  "+ $StateName +"  "+ "Code :"+"  "+ $$getgststatecode:@StateName

          Local: Field: Simple Field: Local Formula:StateName : If NOT ($$IsEmpty:$StateName OR $$IsSysName:NotApplicable:$StateName) Then $StateName Else $LedStateName:Ledger:@PartyName

          Local: Field: Simple Field: Full Width: Yes

          Local: Field: Simple Field: Style: P9

         

[Line:KA Customer GST No]

          Field: Simple Field

          Local: Field: Simple Field: Set as: "GSTIN No : " +"  "+ $PartyGSTIN +"  "+" PAN No :"+"  "+$IncomeTaxNumber:Ledger:$BasicBuyerName

          Local: Field: Simple Field: Full Width: Yes

          Local: Field: Simple Field: Style: P9

         

[Line:KA Customer Contact]

          Field: Simple Field

          Local: Field: Simple Field: Set as: "Contact Details :"+"  "+ @@VchContactNo

          Local: Field: Simple Field: Style: P9

          Local: Field: Simple Field: Full Width: Yes

         

[Part:KA Invoice Details]

          Line: KA Invoice No, KA Invoice Date

          Width: 30% Page

          Border: Thin Left

         

[Line:KA Invoice No]

          Field: Medium Prompt,Simple Field

          Local: Field: Medium Prompt: Set as: "Invoice No."

          Local: Field: Medium Prompt: Style: P9B

          Local: Field: Medium Prompt: Width: 15

          Local: Field: Simple Field: Set as: $VoucherNumber

          Local: Field: Simple Field: Style: P9

          Local: Field: Simple Field: Full Width: Yes

          Space Top:1

         

[Line:KA Invoice Date]

          Field: Medium Prompt, Simple Field

          Local: Field: Medium Prompt: Set as: "Dated"

          Local: Field: Medium Prompt: Style: P9B

          Local: Field: Medium Prompt: Width: 15

          Local: Field: Simple Field: Set as: $Date

          Local: Field: Simple Field: Style: P9

          Local: Field: Simple Field: Full Width: Yes

         

         

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

[Part:KA Coloumn Titles]

          Line:KA Invoice Body Title,KA Invoice Body Title1

          Border: Thick Cover

          Common Border: Yes

[Part: KA Invoice Body]

          Part:KA Invoice Body Coloumns

          Vertical: Yes

          Border: Thin Cover

         

[Part:KA Invoice Body Title]

          Line:KA Invoice Body Title,KA Invoice Body Title1

          Common Border: Yes

         

[Line:KA Invoice Body Title]

          Use: KA Invoice Body Coloumns

         

          Local: Field: Default: Type: String

          Local: Field: Default: Style: P9B

          Local: Field: Default: Align: Center

         

          Local: Field:KA SrNo: Set as: "Sr "

          Local: Field:KA Item Description: Set as: "Item"

          Local: Field:KA Part No: Set as: "Part"

          Local: Field:KA HSN Code: Set as: "HSN "

         

         

          Local: Field:KA Billed Qty: Set as: "Billed"

          Local: Field: KA Rate: Set as: "Rate"

          Local: Field:KA CD Amt:Set as: "CD Amt"

          Local: Field:KA PD Amt:Set as: "PD Amt"

         

          Local: Field:KA Gross Amt: Set as: "Taxable"

         

          Local: Field:KA CGST Rate: Set as: "CGST"

          Local: Field: KA CGST Amt: Set as: "CGST"

          Local: Field:KA SGST Rate: Set as: "SGST"

          Local: Field:KA SGST Amt: Set as: "SGST "

          Local: Field:KA Item Total: Set as: "Total"

         

          Border: Thin Top

          Space Top: 0.25

         

[Line:KA Invoice Body Title1]

          Use: KA Invoice Body Coloumns

         

          Local: Field: Default: Type: String

          Local: Field: Default: Style: P9B

          Local: Field: Default: Align: Center

         

          Local: Field:KA SrNo: Set as: "No"

          Local: Field:KA Item Description: Set as: "Description"

          Local: Field:KA Part No: Set as: "No"

          Local: Field:KA HSN Code: Set as: "Code"

         

          Local: Field:KA Billed Qty: Set as: "Qty"

          Local: Field: KA Rate: Set as: ""

          Local: Field: KA CD Amt: Set as:""

          Local: Field: KA PD Amt: Set as: ""

         

          Local: Field:KA Gross Amt: Set as: "Amount"

          Local: Field:KA CGST Rate: Set as: "%"

          Local: Field: KA CGST Amt: Set as: "Amt"

          Local: Field:KA SGST Rate: Set as: "%"

          Local: Field:KA SGST Amt: Set as: "Amt"

          Local: Field:KA Item Total: Set as: ""

         

          Border: Thin Bottom

          Space Bottom: 0.25

         

[Part:KA Invoice Body Coloumns]

          Line:KA Invoice Body Coloumns

          Repeat:KA Invoice Body Coloumns:Inventory Entries

          Bottom Line: KA Invoice Body Coloumns Total

          Scroll: Vertical

          Float: No

          Common Border: Yes

         

[Line:KA Invoice Body Coloumns]

          Left Field: KA SrNo, KA Item Description

          Right Field: KA HSN Code,KA Billed Qty, KA Rate, KA Gross Amt,KA CGST Rate, KA CGST Amt, KA SGST Rate, KA SGST Amt, KA Item Total

          Space Top: 0.25

         

          Local: Field:KA SrNo: Width: 2

          Local: Field:KA Part No: Width:7

          Local: Field:KA HSN Code: Width: 5

         

          Local: Field:KA Billed Qty: Width: 6

          Local: Field: KA Rate: Width: 6

          Local: Field: KA CD Amt: Width:6

          Local: Field:KA PD Amt:Width:6

         

          Local: Field:KA Gross Amt: Width: 6

          Local: Field:KA CGST Rate: Width: 3

          Local: Field: KA CGST Amt: Width: 6

          Local: Field:KA SGST Rate: Width: 3

          Local: Field:KA SGST Amt: Width: 6

          Local: Field:KA Item Total: Width: 10

         

          Local: Field:KA SrNo: Border: Thin Right

          Local: Field:KA Part No: Border: Thin Left

          Local: Field:KA HSN Code: Border: Thin Left

         

          Local: Field:KA Billed Qty: Border: Thin Left

          Local: Field: KA Rate: Border: Thin Left

          Local: Field: KA CD Amt: Border: Thin Left

          Local: Field:KA PD Amt:Border: Thin Left

         

          Local: Field:KA Gross Amt: Border: Thin Left

          Local: Field:KA CGST Rate: Border: Thin Left

          Local: Field: KA CGST Amt: Border: Thin Left

          Local: Field:KA SGST Rate: Border: Thin Left

          Local: Field:KA SGST Amt: Border: Thin Left

          Local: Field:KA Item Total: Border: Thin Left

         

         

[Field: KA Sr NO]

          Use: Simple Field

          Set as: $$Line

          Format: "No Zero"

          Style:P9

          Align: Center

         

[Field:KA Item Description]

          Use: Simple Field

          Set as: if NOT $$IsSysName:$StockItemName then @@InvItemName else ""

          Style: P9

          Full Width: Yes

          Line:0

         

[Field:KA Part No]

          Use:Simple Field

          Set as: $PartNo:StockItem:$StockItemName

         

[Field:KA HSN Code]

          Use: Simple Field

          Set as: $$GetGSTItemDetails:$StockItemName:$date:"HSNCode":0:"StockItem";$VJSTKIHSNCode:StockItem:$StockItemName

          Style:P9

         

[Field:KA Billed Qty]

          Use: Qty Primary Field

          Set as: $BilledQty

          Style:P9

         

[Field:KA Rate]

          Use:  Rate Price Field

          Set as: $Rate

          Style:P9

         

[Field:KA CD Amt]

          Use: Amount Field

          Set as: $KACD

          Style: P9

         

[Field:KA PD Amt]

          Use:Amount Forex Field

          Set as: $KAPD

          Style:P9

         

[Field:KA Gross Amt]

          Use:Amount Forex Field

          Set as: $Amount

          Style:P9

         

[Field:KA CGST Rate]

          Use: Number Field

          Set as: If NOT $GSTIsTransLedEx Then "" Else $GSTClsfnIGSTRateEx /2

          Format      : "NoZero,Percentage"

          Set Always: Yes

          Style:P9

[Field:KA CGST Amt]

          Use: Amount Field

          Set as: $Amount * #KACGSTRate / 100

          Style:P9

          Set Always: Yes

         

[Field:KA SGST Rate]

          Use: Number Field

          Set as: If NOT $GSTIsTransLedEx Then "" Else $GSTClsfnIGSTRateEx /2

          Format      : "NoZero,Percentage"

          Set Always: Yes

          Style:P9

         

[Field:KA SGST Amt]

          Use: Amount Field

          Set as: $Amount * #KASGSTRate / 100

          Style:P9

          Set Always: Yes

         

[Field:KA Item Total]

          Use: Amount Field

          Set as: #KAGrossAmt + #KACGSTAmt + #KASGSTAmt

          Set Always: Yes

          Style:P9

         

[Line:KA Invoice Body Coloumns Total]

          Use: KA Invoice Body Coloumns

         

          Local: Field: Default: Type: String

          Local: Field: Default: Style: P9B

          Local: Field: Default: Align: Center

         

          Local: Field:KA SrNo: Set as: ""

          Local: Field:KA Item Description: Set as: "TOTAL"

          Local: Field:KA HSN Code: Set as: ""

         

          Local: Field: KA Rate: Set as: ""

          Local: Field: KA CD Amt: Set as:""

          Local: Field:KA PD Amt:Set as:$$CollAmtTotal:InventoryEntries:$AssoValue

          Local: Field:KA Gross Amt: Set as: $$CollAmtTotal:InventoryEntries:$Amount

         

          Local: Field:KA CGST Rate: Set as: ""

          Local: Field: KA CGST Amt: Set as: $$FilterAmtTotal:LedgerEntries:CGST1:$Amount

          Local: Field:KA SGST Rate: Set as: ""

          Local: Field:KA SGST Amt: Set as: $$FilterAmtTotal:LedgerEntries:SGST1:$Amount

          Local: Field:KA Item Total: Set as: $Amount

          Border: Thin Top Bottom

          Space Bottom: 0.25

          Space Top: 0.25

         

[System: Formula]

          SGST                                                                    :$$FilterAmtTotal:LedgerEntries:SGST1:$Amount

          SGST1                                                                            :$Name:Ledger:$LedgerName Contains $$LocaleString:"SGST"

         

          CGST                                                                    :$$FilterAmtTotal:LedgerEntries:CGST1:$Amount

          CGST1                                                                           :$Name:Ledger:$LedgerName Contains $$LocaleString:"CGST"

         

[Part:KA Invoice Total]

          Right Part: KA Ledger Entries

          Left Part: KA Invoice Sing Off

          Border: Thick Box

         

[Part:KA Ledger Entries]

          Line:KA Ledger Entries

          Repeat:KA Ledger Entries:Ledger Entries

         

          Float: No

          Common Border: Yes

          Bottom Line: KA Invoice Total

         

[Line:KA Invoice Total]

          Field: KA Invoice Total Title, KA Invoice Total Amt

         

[Field:KA Invoice Total Title]

          Use: Simple Field

          Set as:"INVOICE TOTAL"

          Style: Large Bold

          Width:20.7

         

[Field:KA Invoice Total Amt]

          Use: Amount Field

          Set as: $Amount

          Style: Large Bold

          Width:10

          Border: Thin Left

         

[Line: KA Ledger Entries]

          Remove if    : $LedgerName = $PartyLedgerName

          Field: KA Ledger Name, KA Ledger Amount

          Space Top: 0.5

          Border: Thin Bottom

         

[Field: KA Ledger Name]

          Use: Simple Field

          Set as: $LedgerName

          Style:P9B

          Width: 20.7

          Border: Thin Left

         

[Field:KA Ledger Amount]

          Use: Amount Field

          Set as: $Amount

          Style:P9B

          Width: 10

          Border: Thin Left

          Align: Right

         

[Part:KA Invoice Sing Off]

          Part: KA Amount In Word and Declaration, KA Invoice Sing Off Part

          Vertical: Yes

         

[Part:KA Amount In Word and Declaration]

          Line: KA Amount In Word, KA Declaration

         

[Line:KA Amount In Word]

          Field: Simple Field

          Local: Field: Simple Field: Set as: "TOTAL VALUE (IN WORDS) Rs." +"  "+ $$InWords:$Amount

          Local: Field: Simple Field: Full Width: Yes

          Local: Field: Simple Field: Style: P9B

          Local: Field: Simple Field: Line:0

         

[Line:KA Declaration]

          Field: Simple Prompt,Simple Field

          Local: Field: Simple Prompt: Set as: "Declaration"

          Local: Field: Simple Prompt: Style: P9

          Local: Field: Simple Field: Set as: "Certified that the Particulars given above are true and correct."

          Local: Field: Simple Field: Line: 0

          Local: Field: Simple Field: Full Width: Yes

          Local: Field: Simple Field: Style: P9

          Space Top: 0.5

         

[Part:KA Invoice Sing Off Part]

          Left Part: For KA

          Right Part: For KA Cu

         

[Part:For KA]

          Line: For KA, KA Authorised Signatory

         

[Line: For KA]

          Field: Simple Field

          Local: Field: Simple Field: Set as: "For" +"  "+ @@CmpMailName

          Local: Field: Simple Field: Full Width: Yes

          Local: Field: Simple Field: Style: P9B

          Local: Field: Simple Field: Align: Left

          Space Top: 1

         

[Line:KA Authorised Signatory]

          Field: Simple Field

          Local: Field: Simple Field: Set as: "Authorised Signatory"

          Local: Field: Simple Field: Full Width: Yes

          Local: Field: Simple Field: Style: P9B

          Local: Field: Simple Field: Align: Left

          Space Top:2

         

[Part:For KA Cu]

          Line:For KA Cu

         

[Line:For KA Cu]

          Field: Simple Field

          Local:Field: Simple Field: Set as: "Receivers Stamp & Sign."

          Local:Field: Simple Field: Full Width: Yes

          Local: Field: Simple Field: Align: Right

          Local: Field: Simple Field: Style: P9

          Space Top:4

         

[Part:KA Goods Sold]

          Line:KA Goods Sold, KA Juridiction

         

[Line:KA Goods Sold]

          Field: Simple Field

          Local: Field: Simple Field: Set as: "GOODS ONCE SOLD WILL NOT BE TAKEN BACK"

          Local: Field: Simple Field: Align: Center

          Local: Field: Simple Field: Full Width: Yes

          Local: Field: Simple Field: Style: P9B

         

[Line:KA Juridiction]

          Field: Simple Field

          Local: Field: Simple Field: Set as: "JURISDICTION NASHIK"

          Local: Field: Simple Field: Align: Center

          Local: Field: Simple Field: Full Width: Yes

          Local: Field: Simple Field: Style: P9B